** TESTBOOT.AS_7 **************************************************************
*    ENTREE: rien                                                             *
*                                                                             *
*    SORTIE: Message seriel repete sur SCI                                    *
*                                                                             *
*    FONCTION: Renseigne sur la liaison serielle en mode BootStrap            *
* AVEC OFFSET= REGBAS= $1000, mode X indexe  pointeur MESSAGE sur index Y     *
* révision D.M. le 26 09 2001 *
* Utilise l'interruption SWI pour la conversion Hexa \ ASCII
******************************************************************************
*******************************************************************************
*  Mode monochip du 68HC811E2 *
* *
* Dernière révision D.M. le 19/09/2001 - Lycée Pape Clément - PESSAC *
* Votre Nom: ? *
*******************************       Nom du fichier:  ?            .asm *****
* Association SoFt : assoft@aol.com *
* http://members.aol.com/assoft/home.htm    ***** *
* Auteur DevMic11 :- Bernard Reynier XWre@aol.com *
*******************************************************************************

VecteurRESET    Org $fffe    ; pour un fonctionnement ultérieuren mode MONOCHIP sans DEVmic11
                fdb START    ; placer l'adresse de départ du programme à tester

                include c:\hc11\regbas.asm ; chemin de la table d'équivalence des registres et adresses
START 		 equ $f9a3 ; adresse d'execution après le moniteur
FCCZONE       equ   $80           ;Zone caracteres ASCII a transmettre
*********** CODES ASCII
LF            equ   $0A           ;Ligne suivante
CR            equ   $0D           ;Retour chariot
SPACE         equ   $20           ;Espace
POINT         equ   $2E           ;Point
**********
              org   START         ;**** debut programme ****
*
              sei                 ;inhibe interuptions
              lds   #RAMUEND      ;pile en RAM
              ldx   #REGBAS       ;pointeur X registres internes
              clr   MOTHEX        ;adresse de comptage de la phrase
              clr   MOTHEX+1
DEBUT         ldy   #MESSAGE      ;pointeur Y zone message
              bsr   OUTSTR        ;ENVOI MESSAGE
              bra   DEBUT         ;NOUVEAU MESSAGE
*
*** Sort Accumulateur A sur port serie SCI. ***
*
OUTSCI        asl   SCSR,X        ;TantQue tdre=1 Faire {rien}
              bhs   OUTSCI        ;Test bit registre de transmission plein
              staa  SCDR,X        ;sort le charactere
              jsr   TEMPO10       ;attente 10 ms 
              rts
*
*** SORTIE MESSAGE
OUTSTR        swi                 ;Interruption logicielle
OUTSTRING     ldaa  0,Y
              bsr   OUTSCI        ;sortie TxD
              iny
              cmpa  #CR
              bne   OUTSTRING
              rts
*
$include "A:\TEMPO10.ASM"	; vérifiez ce chemin d'acces !

***********************************
* Interruption logicielle
HEX_ASC       ldx   #MOTHEX+1
              ldy   #MOTASC+3
ENCOR         ldaa  0,X
              bsr   CONVASCHEX
              ldaa  0,X
              asra
              asra
              asra
              asra
              bsr   CONVASCHEX
              dex
              cpx   #MOTHEX
              bhs   ENCOR
              ldx   MOTHEX
              inx
              stx   MOTHEX
              rti
* Sous routine d'interruption
CONVASCHEX    anda  #$0F
              cmpa  #$09
              bls   ADD30
ADD37         adda  #$07
ADD30         adda  #$30
              staa  0,Y
              dey
              rts
**********************************
              org   VSWI          ; mode  BOOTSTRAP
              fcb   $7E           ; JMP adressage etendu
              fdb   HEX_ASC       ;Debut du programme d'interruption SWI
**********************************
              org   FCCZONE       ;Origine zone d'implantation MESSAGE
*
*** message a transmettre sur sci ***
*
MESSAGE       fcc    'Cette carte fonctionne en mode Bootstrap'
              fcb   SPACE,POINT,POINT,POINT
MOTASC        rmb   4             ;Emplacement du numero de phrase en ASCII
              fcb   SPACE,POINT,LF,CR
MOTHEX        rmb   2             ;Emplacement du numero en Hexadecimal
              end
*